• 2D 画布和文本布局；
• CPU 软件光栅化；
• GPU 加速渲染；
• 从右到左的渲染；
• SVG 渲染和创建；
• PDF 输出；
• 运行时效果；
• 着色语言；
• 着色器、遮罩和颜色过滤器；
• 图像和路径效果；
• 动画图像播放器（Lottie、GIF、WebP）；
• 图像编解码器（bmp、gif、ico、jpg、png、wbmp、webp 和原始图像）等。

• 在任何平台上以抗锯齿方式绘制（绘图质量基于 Form.Quality 属性）；
• 将应用程序的整体图形性能提高多达 50%（即使以更高的质量进行绘制）；
• 以更高的质量调整图像大小（也基于 Form.Quality）；
• 支持从右到左的文本渲染；
• 修复数十处绘图中的不一致问题（尤其是在角落和笔画处，例如虚线，以及带有特殊表情符号的文本）；
• 提高库的整体性能（包括控件、绘图等）。

1. 安装程序（推荐）
   下载最新版本的安装程序并安装。

   

    

2. Skia4Delphi 安装
   使用 Embarcadero 的 GetIt（RAD Studio > Tools > GetIt Package Manager…）进行安装。

   

    

3. Chocolatey 包管理器
   在命令行中运行以下命令安装：

   choco install skia4delphi

uses
  System.Skia;

type
  TSkDrawExampleProc = reference to procedure(const ACanvas: ISkCanvas; const ADest: TRectF);

procedure DrawExample(const AWidth, AHeight: Integer; const ADrawProc: TSkDrawExampleProc);
begin
  var LSurface := TSkSurface.MakeRaster(AWidth, AHeight);
  LSurface.Canvas.Clear(TAlphaColors.Null);
  ADrawProc(LSurface.Canvas, RectF(0, 0, AWidth, AHeight));
  LSurface.MakeImageSnapshot.EncodeToFile('output.png');
end;

基本用法
以下代码展示了如何绘制图形：

DrawExample(256, 256,
  procedure (const ACanvas: ISkCanvas; const ADest: TRectF)
  begin
    var LPaint: ISkPaint := TSkPaint.Create;
    LPaint.AntiAlias := True;

    LPaint.Color := $FF4285F4;
    var LRect := TRectF.Create(PointF(10, 10), 100, 160);
    ACanvas.DrawRect(LRect, LPaint);

    var LOval: ISkRoundRect := TSkRoundRect.Create;
    LOval.SetOval(LRect);
    LOval.Offset(40, 80);
    LPaint.Color := $FFDB4437;
    ACanvas.DrawRoundRect(LOval, LPaint);

    LPaint.Color := $FF0F9D58;
    ACanvas.DrawCircle(180, 50, 25, LPaint);

    LRect.Offset(80, 50);
    LPaint.Color := $FFF4B400;
    LPaint.Style := TSkPaintStyle.Stroke;
    LPaint.StrokeWidth := 4;
    ACanvas.DrawRoundRect(LRect, 10, 10, LPaint);
  end);

运行效果如下图：

PDF
使用 Skia4Delphi，可以创建 PDF 文档，并在其中绘制任何内容，包括文本和图像。以下示例展示了如何创建一个 PDF 文档并在其中绘制一个 SVG 图像：

var LSVGDOM := TSkSVGDOM.MakeFromFile('Samples\Demo\Assets\lion.svg');
  var LSize := TSizeF.Create(600, 600);
  LSVGDOM.SetContainerSize(LSize);

  var LDocumentStream := TFileStream.Create('output.pdf', fmCreate);
  try
    var LDocument := TSkDocument.MakePDF(LDocumentStream);
    try
      var LCanvas := LDocument.BeginPage(LSize.Width, LSize.Height);
      try
        // Draw anything here with Skia canvas
        LSVGDOM.Render(LCanvas);
      finally
        LDocument.EndPage;
      end;
    finally
      LDocument.Close;
    end;
  finally
    LDocumentStream.Free;
  end;

运行效果如图：

编解码器（Codecs）

Skia4Delphi 库支持多种图像格式。以下是支持的格式列表：

支持的解码格式

注意：原始图像格式（Raw）仅限于非 Windows 平台。

支持的编码格式

关于 WebP

WebP 是一种现代图像格式，为图像提供了卓越的无损和有损压缩。

• WebP 无损图像比 PNG 小 26%。

• WebP 有损图像在同等质量下比 JPEG 小 25%-34%。

以下示例演示了如何将图像编码为 WebP 格式：

var LImage := TSkImage.MakeFromEncodedFile('Samples\Demo\Assets\kung-fu-panda.png');
  LImage.EncodeToFile('output.webp', TSkEncodedImageFormat.WEBP, 80);
  LImage.EncodeToFile('output.jpg', TSkEncodedImageFormat.JPEG, 80);

运行效果如图：

uses
  System.Skia, FMX.Skia {or Vcl.Skia};

...

  var LBitmap := TBitmap.Create(100, 100);
  try
    LBitmap.SkiaDraw(
      procedure (const ACanvas: ISkCanvas)
      begin
        // Draw with Skia canvas...
      end);

图像格式

• VCL: .svg, .webp, .wbmp 和原始图像 (.arw, .cr2, .dng, .nef, .nrw, .orf, .raf, .rw2, .pef 和 .srw)。
• FMX: .bmp, .gif, .ico, .webp, .wbmp 和原始图像 (.arw, .cr2, .dng, .nef, .nrw, .orf, .raf, .rw2, .pef 和 .srw)。

FMX 渲染

启用 Skia 渲染

uses
  System.StartUpCopy,
  FMX.Forms,
  FMX.Skia,
  Unit1 in 'Unit1.pas' {Form1};

{$R *.res}

begin
  GlobalUseSkia := True;
  Application.Initialize;
  ...

注意事项

1. FMX.Skia 单元必须在 FMX.Forms 之后包含；
2. Skia Metal 渲染可以通过在 FMX.Forms 之后包含 FMX.Types 单元，并将 GlobalUseMetal 与 GlobalUseSkia 一起设置为 True，以提高 iOS 和 macOS 上的速度；
3. Skia Vulkan 渲染可以在 RAD Studio 12 Athens 或更高版本中使用，通过在 FMX.Forms 之后包含 FMX.Types 单元，并将 GlobalUseVulkan 与 GlobalUseSkia 一起设置为 True，以提高 Android 和 Windows 上的速度。在 Windows 上，只有同时添加 GlobalUseSkiaRasterWhenAvailable := False; 时才会使用 Vulkan；
4. GlobalUseSkia := True; 的声明以及 FMX 的其他变量（如 GlobalUseMetal）也可以在 .dpr 文件的初始化部分中完成。有时这是非常必要的，因为如果在某个单元的初始化或类构造函数中使用了位图，则 .dpr 中的 GlobalUseXXX 声明将无效。在这种情况下，只需在项目中创建一个名为 “Project.Startup.pas” 的单元，将 GlobalUseXXX 声明放在该单元的初始化部分，并在 .dpr 文件中将其声明在您的任何其他单元之前，即在 FMX.Forms 之后。

基准测试

uses
  System.Skia, FMX.Skia.Canvas;

begin
  var LBitmap := TBitmap.Create(300, 300);
  try
    LBitmap.Canvas.BeginScene;
    try
      var LCanvas: ISkCanvas := TSkCanvasCustom(LBitmap.Canvas).Canvas;
      // 使用 Skia 画布（LCanvas）直接绘制以解锁新功能...
    finally
      LBitmap.Canvas.EndScene;
    end;
  finally
    LBitmap.Free;
  end;
end;

type
  TMyControl = class(TControl)
  protected
    procedure Paint; override;
  end;

implementation

uses
  System.Skia, FMX.Skia.Canvas;

procedure TMyControl.Paint;
begin
  var LCanvas: ISkCanvas := TSkCanvasCustom(Canvas).Canvas;
  // 使用 Skia 画布（LCanvas）直接绘制以解锁新功能...
end;

procedure TForm1.SkPaintBox1Draw(ASender: TObject; const ACanvas: ISkCanvas;
  const ADest: TRectF; const AOpacity: Single);
begin
  var LPaint: ISkPaint := TSkPaint.Create;
  LPaint.Shader := TSkShader.MakeGradientSweep(ADest.CenterPoint,
    [$FFFCE68D, $FFF7CAA5, $FF2EBBC1, $FFFCE68D]);
  ACanvas.DrawPaint(LPaint);
end;

var LSvg := TSkSvg.Create(Self);
  LSvg.Svg.Source := TFile.ReadAllText('Samples\Demo\Assets\panda.svg');
  LSvg.Parent := Self;